ざきさんさん:

すいません、いただいたコメント、今気づきました。
BASIC認証かかっていますね。

以下のサンプルを参考にしてください。
(同様の認証がかかっているウチの秘密サイトで動作確認済です)

Option Explicit

'required:
'microsoft xml 6,0.
'microsoft html object library
'micrsoft internet controls

'必要事項:
'[1] Base64エンコードされたid, passwordの文字列を生成する
'[2] [1]をリクエスト時のヘッダー情報に含める
'[3] リクエストを実行する
Sub BasicCertificationLogin()
    Dim sId As String   '認証id
    Dim sPass As String '認証pass
    Dim sEnc As String  'base64エンコード済id:pass文字列
    sId = "myid"
    sPass = "mypass"
    sEnc = EncodeBase64(sId & ":" & sPass) '[1]
    
    Dim sHead As String
    sHead = "Authorization: Basic " & sEnc & vbCrLf  '[2]
    
    Dim url As String
    url = "http://foo.bar/"
    
    Dim objIE As New InternetExplorer
    objIE.Visible = True
    
    objIE.navigate url, , , , sHead '[3]
End Sub
Function EncodeBase64(st As String) As String
  Dim arrData() As Byte
  arrData = StrConv(st, vbFromUnicode)

  Dim objXML As MSXML2.DOMDocument60
  Dim objNode As MSXML2.IXMLDOMElement

  Set objXML = New MSXML2.DOMDocument60
  Set objNode = objXML.createElement("b64")

  objNode.DataType = "bin.base64"
  objNode.nodeTypedValue = arrData
  EncodeBase64 = objNode.text

  Set objNode = Nothing
  Set objXML = Nothing
End Function

> 返信ありがとうございます。
> アプリという表現が正しかったのかわかりませんが、サイト上で顧客管理をしています。ここでURLをさらしていいのかわからなかったので、添付ファイルにて、ＵＲＬを送ります。

2019/04/08 18:25