たかちゃんさん:

おはようございます。

発展編１でworksheetfunctionの活用を学びます(テキスト参照)。それを活用すると以下のような感じです。

> For eachではcやcyokoなどの変数を使ってピンポイントで指定して書くことはできないのだと気付きました。（コレクションのプロパティを指定する時に使うものだから。）

セルを取得すればその .Row, .Column プロパティを取得できますので、これを元にして、あるセルを起点にそのセルについて示したラベルの値(この事例であれば、名前とか月とか)を取得可能です。

Sub set_max_value_data()
    '最大値を取得 worksheetfunction.max 使用
    Dim rgAll As Range
    Set rgAll = Range("C6:H33")
    
    Dim rg As Range
    Dim mx As Double
    mx = WorksheetFunction.Max(rgAll)
    
    Set rg = rgAll.Find(What:=mx, LookAt:=xlWhole)
        
    Range("K4").Value = Range("B" & rg.Row).Value
    Range("L4").Value = Range("A5").Offset(, rg.Column - 1).Value
    Range("M4").Value = mx
End Sub

Sub get_ranking_from_1_to_10()
    'ランク取得 worksheetfunction.rank 使用
    '5位以降は複数のデータが同順の場合があるので説明略(発展編2まで学習が進むと効率的なやり方があります)
    Range("O5").Value = "順位"
    Range("P5").Value = "数値"
    Dim rgAll As Range
    Set rgAll = Range("C6:H33")
    
    Dim rg As Range
    Dim iRank As Long
    For Each rg In rgAll
        iRank = WorksheetFunction.Rank(rg.Value, rgAll, 0)
        If iRank < 6 Then
            Range("O5").Offset(iRank).Value = iRank & "位"
            Range("P5").Offset(iRank).Value = rg.Value
        End If
    Next
End Sub

2020/10/13 18:37

小川慶一さん:

先生、ありがとうございます。頂いたコードを読み解きながら手を動かしているうちに記憶が蘇ってきました。
毎日、End(xlup).rowを使っているにも関わらず、.rowや.colomnのプロパティをすっかり忘れていました。

For EachとOffsetでなんとかできないかインターネットで調べていた時に、どこかのサイトで「できない」と断言されていて、すっかり出来ないのだと思い込んでいました。

Worksheetfunction.maxを使えばこんなにもあっさり出来てしまうんですね。ついついFor文などで一つ一つ調べることに気を取られて発展編１の最後で勉強したのにも関わらず、このアイデアは思いつきませんでした。
ランキングも、自力で作成した時は、変数ichiban 、niban、、、と作ってIf文で振り分けて格納してから並べていました。
Range("O5").Offset(iRank).Value = iRank & “位”を見た時、発展編１のあの方法か！と気付きました。つい２日位前まで毎日書いていたのに、こちらも全く気付きませんでした。これからは並び替えに困ったら、この方法で出来ないか１番に考える様にします。

実践は全然違いますね。。。（^^;;　今回頂いたコードは忘れないよう印刷して暫く毎日練習します。毎回、ありがとうございます。

> たかちゃんさん:
>
> おはようございます。
>
> 発展編１でworksheetfunctionの活用を学びます(テキスト参照)。それを活用すると以下のような感じです。
>
> > For eachではcやcyokoなどの変数を使ってピンポイントで指定して書くことはできないのだと気付きました。（コレクションのプロパティを指定する時に使うものだから。）
>
> セルを取得すればその .Row, .Column プロパティを取得できますので、これを元にして、あるセルを起点にそのセルについて示したラベルの値(この事例であれば、名前とか月とか)を取得可能です。
>
>

Sub set_max_value_data()
>     '最大値を取得 worksheetfunction.max 使用
>     Dim rgAll As Range
>     Set rgAll = Range("C6:H33")
>     
>     Dim rg As Range
>     Dim mx As Double
>     mx = WorksheetFunction.Max(rgAll)
>     
>     Set rg = rgAll.Find(What:=mx, LookAt:=xlWhole)
>         
>     Range("K4").Value = Range("B" & rg.Row).Value
>     Range("L4").Value = Range("A5").Offset(, rg.Column - 1).Value
>     Range("M4").Value = mx
> End Sub
> 
> Sub get_ranking_from_1_to_10()
>     'ランク取得 worksheetfunction.rank 使用
>     '5位以降は複数のデータが同順の場合があるので説明略(発展編2まで学習が進むと効率的なやり方があります)
>     Range("O5").Value = "順位"
>     Range("P5").Value = "数値"
>     Dim rgAll As Range
>     Set rgAll = Range("C6:H33")
>     
>     Dim rg As Range
>     Dim iRank As Long
>     For Each rg In rgAll
>         iRank = WorksheetFunction.Rank(rg.Value, rgAll, 0)
>         If iRank < 6 Then
>             Range("O5").Offset(iRank).Value = iRank & "位"
>             Range("P5").Offset(iRank).Value = rg.Value
>         End If
>     Next
> End Sub

>

2020/10/14 10:35

受講生 さん:

おはようございます。

> 毎日、End(xlup).rowを使っているにも関わらず、.rowや.colomnのプロパティをすっかり忘れていました。
> 今回頂いたコードは忘れないよう印刷して暫く毎日練習します。

まあ...こうやってアイデアがだんだんついてくるものです。
何回か書けばしっくりくるかと思います。

ひきつづき、よい学びを☆

2020/10/15 18:58