ゲストさん:

まずは、基礎編の以下でお伝えした原則がありますね。

「基礎講座第１章２ - オブジェクトの指定」
https://forum.pc5bai.com/lesson/page/98

複数セルを含む範囲の指定は、

Sub hoge1()
    Range("A1:F7").Select '[1]
End Sub

のように書けます（他の方法もありますが、そこがご質問の核になる部分ではないので、今は紹介省略）

上記 [1] は、以下の [2] のようにも書けます。これは、基礎編第２章。

Sub hoge2()
    Range("A1:F" & "7").Select  '[2]
End Sub

そして、以下からは、発展編１で学んだネタと組み合わせます。
調整数型変数 mx で、F列の最終行のセルの行番号を調べましょう。

Sub hoge3()
    Dim mx As Long
    mx = Range("F1048576").End(xlUp).Row '[3]
End Sub

[2], [3]より、以下となります。

Sub hoge4()
    Dim mx As Long
    mx = Range("F1048576").End(xlUp).Row '[4-1]
    Range("A1:F" & mx).Select            '[4-2]
End Sub

あるいは、以下の [5] でもOK。

Sub hoge5()
    Range("A1:F" & Range("F1048576").End(xlUp).Row).Select  '[5]
End Sub

For Each 構文の範囲指定に使うということであれば、[5]の .Select より前を取り出して、以下ですね。

Sub hoge6()
    Dim r As Range
    For Each r In Range("A1:F" & Range("F1048576").End(xlUp).Row) '[6]
        Debug.Print r.Address
    Next
End Sub

もっとも、こんなのはじめから書ける必要はありません。
もっと分解して、まずはこんなところからできればいいんじゃないでしょうか↓。

Sub hoge7()
    Dim r As Range
    Dim rAll As Range                                          '[7-1]
    Set rAll = Range("A1:F" & Range("F1048576").End(xlUp).Row) '[7-2]
    For Each r In rAll                                         '[7-3]
        Debug.Print r.Address
    Next
End Sub

というか、たぶん上記[7]でも難しいかと思います。
ということで、さらに分解。最初の最初は、こんなところからできるようになればよいかと↓。

Sub hoge8()
    Dim r As Range
    Dim rAll As Range                    '[8-1]
    Dim mx As Long                       '[8-2]
    mx = Range("F1048576").End(xlUp).Row '[8-3]
    Set rAll = Range("A1:F" & mx)        '[8-4]
    For Each r In rAll                   '[8-5]
        Debug.Print r.Address
    Next
End Sub

もっとも、For Each構文は他の構文と比べて登場する部品が抽象的です。
慣れないうちは、できるだけ具体的にできるところは具体的にしたほうが良いかと思います。[6]のような書き方は、かなり慣れてからでなければお勧めできません。
[6]より[7], [7]より[8]のほうがお勧めですね。
[8]の書き方で書き飽きたら[7], [7]の書き方で書き飽きたら[6]、と進化していってください。

まずは、こんなところで回答としてはいかがでしょうか。

2018/02/03 06:52

小川慶一さん:

下記のご回答ありがとうございます。
練習を重ねてマスターできるよう精進します！

2018/02/04 00:33