Sub GetSumAllCollection() 'Modified by 達人養成塾 Hiroaki Tanaka
    '以下では、すべてのお客さんについて、金額の合計を求める
    Worksheets("Sheet2").Activate
    
    'Collectionを２つ使ってDictionaryを模擬実現
    Dim colkey As Collection: Set colkey = New Collection 'Key
    Dim colitm As Collection: Set colitm = New Collection 'Item
    Dim st As String
    
    '取得系
    Dim cFm As Long, cNo As Long
    For cFm = 2 To 22
        st = Range("B" & cFm).Value
        If cFm > 2 Then
            cNo = keyExistsNumber(colkey, st)
            If cNo = 0 Then
                colkey.Add st
                colitm.Add New Collection
                colitm.Item(colkey.Count).Add cFm
            Else
                colitm.Item(cNo).Add cFm
            End If
        Else
            colkey.Add st
            colitm.Add New Collection
            colitm.Item(colkey.Count).Add cFm
        End If
    Next
    
    '出力系
    Dim col As Variant
    Dim cGokei As Long
    Dim cTo As Long
    cTo = 2
    For cFm = 1 To colkey.Count 'CollectionはIndexが1から始まる
        st = colkey.Item(cFm)
        cGokei = 0
        For Each col In colitm.Item(cFm)
            cGokei = cGokei + Range("G" & col)
        Next
        Range("I" & cTo).Value = st
        Range("J" & cTo).Value = cGokei
        cTo = cTo + 1
    Next
End Sub

'Collectionを検索し、見つかった文字列のItem番号を返す関数
Function keyExistsNumber(col As Collection, key As Variant) As Long
    Dim c As Long
    For c = 1 To col.Count 'CollectionはIndexが1から始まる
        If col.Item(c) = key Then
            keyExistsNumber = c
            Exit Function '見つかったら処理終了
        End If
    Next
    keyExistsNumber = 0   '見つからなかった場合
End Function

Sub GetSumAll_AdvancedFilter() 'Modified by 達人養成塾 Hiroaki Tanaka
    Dim rgBase As Range
    Set rgBase = Range("B1:B" & Range("B" & Rows.Count).End(xlUp).Row)
    '会社のリスト書き出し（タイトル行からの指定がポイント）
    rgBase.AdvancedFilter Action:=xlFilterCopy, CopyToRange:=Range("I1"), Unique:=True

    Dim rg As Range
    'rgBaseの範囲がタイトル行からなので、G列の指定も１行目からする
    For Each rg In Range("I2:I" & Range("I" & Rows.Count).End(xlUp).Row).Cells
        rg.Offset(, 1).Value = Application.WorksheetFunction.SumIf(rgBase, rg.Value, rgBase.Offset(, 5))
    Next
End Sub