Sub GetRequestSimple1_ADO()
    Dim url As String
    url = "http://www.exvba.com/ws/dombasic.html"

    Dim xh As New WinHttp.WinHttpRequest
    xh.Open "GET", url, False
    xh.send
    
    Dim sCode As String
    sCode = xh.Status
    If sCode <> 200 Then
        MsgBox "リクエストに失敗しました" & vbNewLine & sCode
    End If

    'htmlをDOMとして取得する。そのための変数を宣言。
    Dim oHTml As New MSHTML.HTMLDocument
    'oHTml.body.innerHTML = xh.ResponseText 'htmlボディーをDOMとして取得
    '文字化け対策で関数呼び出し
    oHTml.body.innerHTML = get_response_body_encoded(xh, "utf-8")
    
    '所定のIDの要素を取得します
    Dim oH1 As MSHTML.HTMLHeadElement
    Set oH1 = oHTml.getElementById("h1_01")
    Debug.Print oH1.outerHTML
    Debug.Print oH1.innerHTML
    Debug.Print oH1.innerText
    
    '所定の要素の次の要素を取得します
'    Debug.Print oH1.NextSibling.outerHTML
'    Debug.Print oH1.NextSibling.innerHTML
'    Debug.Print oH1.NextSibling.innerText
    Debug.Print oH1.nextElementSibling.outerHTML
    Debug.Print oH1.nextElementSibling.innerHTML
    Debug.Print oH1.nextElementSibling.innerText
    
    'HTMLBody全体を取得します
    Dim oH As MSHTML.HTMLBody
    Set oH = oHTml.getElementsByTagName("body")(0)
    Debug.Print oH.outerHTML
    Debug.Print oH.innerHTML
    Debug.Print oH.innerText
    
    'HtmlBodyの子要素のうち4番目のものを取得します
'    Debug.Print oH.ChildNodes(3).outerHTML
'    Debug.Print oH.ChildNodes(3).innerHTML
'    Debug.Print oH.ChildNodes(3).innerText
    Debug.Print oH.Children(3).outerHTML
    Debug.Print oH.Children(3).innerHTML
    Debug.Print oH.Children(3).innerText
    
    'H2タグのついた要素すべてを順番に調べます
    Dim oH2 As MSHTML.HTMLHeadElement
    For Each oH2 In oHTml.getElementsByTagName("h2")
        Debug.Print oH2.outerHTML
        Debug.Print oH2.innerHTML
        Debug.Print oH2.innerText
    Next
End Sub

'以下に紹介するライブラリの参照設定をしてください
'Microsoft ActiveX Data Objects 2.X Library -> ADOで文字化けを処理するため
Private Function get_response_body_encoded(xh As WinHttp.WinHttpRequest, charset As String)
    Dim byte_body() As Byte
    byte_body = xh.responseBody
    
    Dim ado_stream As New ADODB.Stream
    Dim result As String
     
    ado_stream.Open
    ado_stream.Position = 0
    ado_stream.Type = 1
    ado_stream.Write byte_body
     
    ado_stream.Position = 0
    ado_stream.Type = 2
    ado_stream.charset = charset
    result = ado_stream.ReadText
    ado_stream.Close
    get_response_body_encoded = result
End Function